先祝朋友们：节日快乐！

一，构思：
    我用通达信用主合面版比较多。看盘，分析，选股，操作基本上都在主合面版上。往往一个主合面版上有两到三个分析图，因此一个分析图上就不能有
    较多的副图。在日线主图上，量图必可少。若量图上还有其它指标作用，就不需要多个副图了。【盛唐量图】就基於上述思考而作。

二，【盛唐量图】指标构成；
1，量图是用换手作图。功能与我〈股海看量〉相似，近似的反应买卖盘走势。
   当日用预测量作图。另增四天放大作图以作对比和饱和度作图。饱和度的舍意为；当天的量价系数与20天最大系数之比(参数K=1时这部分图可去掉)。
2,〈同舟共舞〉的主要内容也在其中。【盛唐量图】除日周期外其它周期为纯量图。主合面版的60分和15分的付图用〈同舟共舞〉以便作走势分折。
   多种KD和 MACD(电扦和房子)为主要分析指标。

{盛唐量图}
{参数N:(1,100,5)  K(0,1,0)}
量:V,NODRAW;
换手:IF(PERIOD=5 AND C<300,V/CAPITAL*100,V/3),NODRAW;
DRAWBAND(100,RGB(180,100,100),0,RGB(0,0,0));
DIF:=(EMA(CLOSE,12)-EMA(CLOSE,26))*100/CEILING(C/8)+50;
DEA:=EMA((EMA(CLOSE,12)-EMA(CLOSE,26)),9)*100/CEILING(C/8)+50;
MACD:=(DIF-DEA)*2+50;
注意:=LLV(LOW,10);
防顶:=HHV(H,25);
来到:=EMA((C-注意)/(防顶-注意)*4,4);
VARA:=EMA(REF(CLOSE,1),4);
色彩峰:=(SMA(MAX(CLOSE-VARA,0),6,1)/SMA(ABS(CLOSE-VARA),6,1)*30)+50;
DRAWICON(CROSS(3.5,来到),色彩峰*1.01,13);
DRAWBAND(色彩峰,RGB(00,100,80),50,RGB(0,0,0));
DRAWBAND(50,RGB(0,150,150),0,RGB(0,0,0));
STICKLINE(MACD>=50,50,MACD,4,0),COLOR666666;
STICKLINE(MACD>=50 AND MACD>REF(MACD,1),50,MACD,3,0),COLOREAEAEA;
STICKLINE(MACD<50 AND MACD>REF(MACD,1),50,(50-MACD)*0.5+50,0,0),COLORFFFFFF;
TT:=240/FROMOPEN;
比:=TT;
WJ:=(H+L+C)/3;
V1:=IF(H=L,1,H-MAX(O,C));
V2:=IF(H=L,1,MAX(C,O)-WJ);
V3:=IF(H=L,1,MIN(O,C)-L);
V4:=IF(H=L,1,WJ-MIN(C,O));
V5:=VOL/IF(H=L,4,H-L);
V6:=(V1*V5);
V7:=(V2*V5);
V8:=(V3*V5);
V9:=(V4*V5);
买盘1:=DYNAINFO(23)*比;
卖盘1:=DYNAINFO(22)*比;
买盘2:=IF(ISLASTBAR AND C>300,(V9+V8)*TT,(V9+V8));
卖盘2:=IF(ISLASTBAR AND C>300,(V6+V7)*TT,(V6+V7));
买盘:=IF(ISLASTBAR AND PERIOD=5 AND C<300,买盘1,买盘2);
卖盘:=IF(ISLASTBAR AND PERIOD=5 AND C<300,卖盘1,卖盘2);
买卖差1:=买盘-卖盘;
换手买:=IF(PERIOD=5 AND C<300,买盘/CAPITAL*100,买盘/3);
换手卖:=IF(PERIOD=5 AND C<300,卖盘/CAPITAL*100,卖盘/3);
买卖差:=换手买-换手卖;
买卖:=换手买+换手卖;
昨V:=REF(买卖,1);
昨换手买:=REF(换手买,1);
昨换手卖:=REF(换手卖,1);
前V:=REF(买卖,2);
前换手买:=REF(换手买,2);
前换手卖:=REF(换手卖,2);
大前V:=REF(买卖,3);
大前换手买:=REF(换手买,3);
大前换手卖:=REF(换手卖,3);
最大1:=MAX(大前V,前V);
最大2:=MAX(昨V,买卖);
最大:=MAX(最大1,最大2),NODRAW;
MM0:=最大/58,NODRAW;
MM1:=CONST(INTPART(大前V/MM0)),NODRAW;
MM2:=CONST(INTPART(前V/MM0)),NODRAW;
MM3:=CONST(INTPART(昨V/MM0)),NODRAW;
MM4:=CONST(INTPART(买卖/MM0)),NODRAW;
MM11:=CONST(INTPART(大前换手买/MM0)),NODRAW;
MM22:=CONST(INTPART(前换手买/MM0)),NODRAW;
MM33:=CONST(INTPART(昨换手买/MM0)),NODRAW;
MM44:=CONST(INTPART(换手买/MM0)),NODRAW;
MM111:=CONST(INTPART(大前换手卖/MM0)),NODRAW;
MM222:=CONST(INTPART(前换手卖/MM0)),NODRAW;
MM333:=CONST(INTPART(昨换手卖/MM0)),NODRAW;
MM444:=CONST(INTPART(换手卖/MM0)),NODRAW;
HD :=HIGH-REF(HIGH,1);
LD :=REF(LOW,1)-LOW;
DMP:=EXPMEMA(IF(HD>0&&HD>LD,HD,0),14);
DMM:=EXPMEMA(IF(LD>0&&LD>HD,LD,0),14);
AK:=EMA((DMP-DMM)*1,3)*100+50,COLORFFFFFF;
AD:=EMA((MA(DMP,3)-MA(DMM,3))*1,3)*100+50,COLORFFFFFF;
绝对A:=40/100;
VAR1:=HHV(HIGH,18);
猎熊HIGH:=(VAR1-LOW)/VAR1;
猎熊LOW:=(VAR1-HIGH)/VAR1;
南熊线:=猎熊HIGH;
TR:=EMA(MAX(MAX(HIGH-LOW,ABS(HIGH-REF(CLOSE,1))),ABS(REF(CLOSE,1)-LOW)),N);
PDI:= DMP*100/TR;
MDI:= DMM*100/TR;
ADX:= EMA(ABS(MDI-PDI)/(MDI+PDI)*100,6);
基本超跌线:=MA(HHV(猎熊LOW,N),21);
西熊线:=EMA(COUNT(CLOSE>REF(CLOSE,1),12),3 )/24;
北熊线:=ADX*HHV(南熊线,60)/HHV(ADX,60);
T:=ABS(IF(北熊线+南熊线-西熊线*2>0,北熊线+南熊线-西熊线*2,0));
点熊线:=EMA(T,3);
点熊辅线:=(SLOPE (点熊线,7)+1)*REF(点熊线,1);
DRAWBAND(点熊线*100,RGB(255,00,00),0,RGB(00,00,00));
DRAWBAND(点熊辅线*100,RGB(255,255,00),0,RGB(0,00,00));
STICKLINE(C>=O,0,(换手买+换手卖)*N,2.2,1),COLORRED;
STICKLINE(C<O,0,(换手买+换手卖)*N,2.2,1),COLORFFFF00;
STICKLINE(买卖差>=0,0,换手买*N,1.5,0),COLORRED;
STICKLINE(买卖差>=0 AND C>=MA(C,30),0,换手买*N,2.2,0),COLORRED;
STICKLINE(买卖差>=0,0,换手卖*N,0.8,0),COLOR998800;
STICKLINE(买卖差>=0 AND C>=MA(C,30),0,换手卖*N,1,0),COLORDDCC00;
STICKLINE(买卖差<0,0,换手买*N,1.8,0),COLORRED;
STICKLINE(买卖差<0 AND C>=MA(C,30),0,换手买*N,2.2,0),COLORRED;
STICKLINE(买卖差<0,0,换手卖*N,0.8,0),COLOR998800;
STICKLINE(买卖差<0 AND C>=MA(C,30),0,换手卖*N,1,0),COLORDDCC00;
STICKLINE(1,0,MAX(换手买*N,换手卖*N),0,0),COLORFFFFFF;
VAR11:=(2*CLOSE+HIGH+LOW)/4;
VAR22:=LLV(LOW,34);
VAR33:=HHV(HIGH,34);
散户:= EMA((VAR11-VAR22)/(VAR33-VAR22)*100,13);
新庄:= EMA(0.667*REF(散户,1)+0.333*散户,2);
散户1:=IF(K=0,散户,DRAWNULL);
新庄1:=IF(K=0,新庄,DRAWNULL);
AK1:=IF(K=0,AK,DRAWNULL);
AD1:=IF(K=0,AD,DRAWNULL);
DRAWBAND(散户1,RGB(255,255,00),新庄1,RGB(0,255,00));
DRAWBAND(AK,RGB(255,00,00),AD,RGB(0,255,255));
逢低吸呐:IF(CROSS(散户,新庄) AND 散户<40 AND CURRBARSCOUNT<30,25,10),COLORRED,LINETHICK2;
逢高减磅:IF(CROSS(新庄,散户) AND 新庄>75 AND CURRBARSCOUNT<30,75,90),COLORGREEN,LINETHICK2;
P1:=IF(BARSLAST(CURRBARSCOUNT=MM1),1,0);
P2:=IF(BARSLAST(CURRBARSCOUNT=MM2),1,0);
P3:=IF(BARSLAST(CURRBARSCOUNT=MM3),1,0);
P4:=IF(BARSLAST(CURRBARSCOUNT=MM4),1,0);
STICKLINE(K=0 AND CURRBARSCOUNT=60  AND CONST(P1),94,100,MM1*3,1),COLORFFFF00;
STICKLINE(K=0 AND CURRBARSCOUNT=60  AND CONST(P2),84,90,MM2*3,1),COLORFFFF00;
STICKLINE(K=0 AND CURRBARSCOUNT=60  AND CONST(P3),74,80,MM3*3,1),COLORFFFF00;
STICKLINE(K=0 AND CURRBARSCOUNT=60  AND CONST(P4),64,70,MM4*3,1),COLORFFFF00;
STICKLINE(K=0 AND CURRBARSCOUNT=60  AND CONST(P1 AND REF(C,3)>=REF(O,3)),94,100,MM1*3,1),COLOR0000FF;
STICKLINE(K=0 AND CURRBARSCOUNT=60  AND CONST(P2 AND REF(C,2)>=REF(O,2)),84,90,MM2*3,1),COLOR0000FF;
STICKLINE(K=0 AND CURRBARSCOUNT=60  AND CONST(P3 AND REF(C,1)>=REF(O,1)),74,80,MM3*3,1),COLOR0000FF;
STICKLINE(K=0 AND CURRBARSCOUNT=60  AND CONST(P4 AND C>=O),64,70,MM4*3,1),COLOR0000FF;
STICKLINE(K=0 AND CURRBARSCOUNT=60  AND CONST(P1),94.5,99.5,MM11*3,0),COLOR0000FF;
STICKLINE(K=0 AND CURRBARSCOUNT=60  AND CONST(P2),84.5,89.5,MM22*3,0),COLOR0000FF;
STICKLINE(K=0 AND CURRBARSCOUNT=60  AND CONST(P3),74.5,79.5,MM33*3,0),COLOR0000FF;
STICKLINE(K=0 AND CURRBARSCOUNT=60  AND CONST(P4),64.5,69.5,MM44*3,0),COLOR0000FF;
STICKLINE(K=0 AND CURRBARSCOUNT=60  AND CONST(P1),96,98,MM111*3,0),COLORFFFF00;
STICKLINE(K=0 AND CURRBARSCOUNT=60  AND CONST(P2),86,88,MM222*3,0),COLORFFFF00;
STICKLINE(K=0 AND CURRBARSCOUNT=60  AND CONST(P3),76,78,MM333*3,0),COLORFFFF00;
STICKLINE(K=0 AND CURRBARSCOUNT=60  AND CONST(P4),66,68,MM444*3,0),COLORFFFF00;
STICKLINE(K=0 AND CURRBARSCOUNT=60  AND C>0,0,100,0,0),COLOR00FFFF;
SAT:=((买盘+卖盘)/C)/(HHV(V,20)/HHV(C,20));
量能饱和:=IF(SAT>1,1,SAT)*100;
STICKLINE(K=0 AND CURRBARSCOUNT=60,48 ,38,100,1),COLOR00DDDD;