//默认值是N1：3，N2：5，N3：8，N4：13 // 1.蓝线B：鳄鱼的颚。取 N4根bar的平滑移动平均，将结果往未来的方向移动N3根bar得到。
DOWN = REF(SMA(CLOSE, N4, 1),N3);
下 : DOWN , colorgreen,LINETHICK2;
// 2.红线R：鳄鱼的牙齿。取N3根bar的平滑移动平均，将结果往未来的方向移动N2根bar得到。
BASE = REF(SMA(CLOSE, N3, 1), N2);
基准 : BASE , colorblue,LINETHICK2;
// N1.绿线G：鳄鱼的上唇。取N2根bar平滑移动平均数，将结果往未来的方向移动N1根bar得到。
UP = REF(SMA(CLOSE, N2, 1), N1);
上 : UP, colorred,LINETHICK2;
// 1.AO，市场最好的动量指标。测量最近N2个价咯bar的动能，并与过去34个bar作比较。等于过去N2个bar的（最高点+最低点）/2取移动平均-过去34个bar的（最高点-最低点）/2取移动平均。
TP01 = ( HIGH + LOW ) / 2;
AO := SMA(TP01, N2, 1) - SMA(TP01, 34, 1);
REG : FORCAST(C,BARSCOUNT(C)),colorgray,LINETHICK2;
// 2.AC，领先动能的指标。AO与其N2日简单移动平均的差值再做N2日简单移动平均。
AC := SMA(AO - SMA(AO, N2, 1), N2, 1);
ISBULL = AO > REF(AO, 1) AND AC > REF(AC, 1);
ISBEAR = AO < REF(AO, 1) AND AC < REF(AC, 1);
IF BARSLAST(ISBULL) < BARSLAST(ISBEAR) THEN
FLAG = 1;
ELSE
FLAG = -1;
IF ( ISBULL ) THEN
{
// 1.红色区域：强劲的多头市场。加仓条件是，AO上行，AC上行，价咯收盘于更高位置
FLAG = 1;
STICKLINE(1,O,C,9,0),colorred;
STICKLINE(1,H,L,1,0),colorred;
}
ELSE IF ( ISBEAR ) THEN
{
// 2.绿色区域：强劲的空头市场。清仓。（原加仓条件，AO下行，AC下行，价咯收盘于更低位置。）
FLAG = -1;
STICKLINE(1,O,C,9,0),RGB(0,128,64);
STICKLINE(1,H,L,1,0),RGB(0,128,64);
}
ELSE
{
// 3.黄s区域：过渡期。不操作。
IF FLAG = 1 THEN
{
STICKLINE(1,H,L,1,0),colorlired;
STICKLINE(1,C,O,9,0),colorlired;
}
ELSE
{
STICKLINE(1,H,L,1,0),colorblue;
STICKLINE(1,C,O,9,0),colorblue;
}
INTER = ABS(H-L)*0.3;
IF F3 = 1 THEN
{
IF AO > 0 THEN
{
IF AC > REF(AC, 1) THEN
DRAWICON(1,H+INTER ,'红实圆');
ELSE
DRAWICON(1,H+INTER ,'红圆圈');
}
ELSE
{
IF AC > REF(AC, 1) THEN
DRAWICON(1,L-INTER ,'绿实圆');
ELSE
DRAWICON(1,L-INTER ,'绿圆圈');
}
}
}
// A.经典碎形：N2根bar组成，中间的高点一定最高，左右各两根线有较低高点。分辨向上碎形时，只关注高点位置。
// B.向上与向下碎形共享外围bar
// C.向上、向下碎形由一根bar完成
// D.如今天高点与之前高点相同，今天的bar不算在N2根bar之内
INTER = ABS(H-L)*0.5;
IF F1=1 THEN
{
//画下分型
LVALUE = REF(LLV(LOW, N1),1);
LFEN = (LVALUE = REF(LLV(LOW, N1),N1) AND LVALUE < REF(BASE,N1));
HORLINE(LFEN ,LVALUE,3,2),RGB(0,128,64),LINETHICK2;
DAYS = BARSLAST(LFEN);
LV = REF(REF(LLV(LOW, N1),DAYS),1);
//DRAWTEXT(1,L-INTER,LV),colorblack;
LLAST = C<LV OR O<LV;
IF LLAST AND REF(LLAST,1) < 1 THEN
DRAWICON(1,L-INTER ,'sell1');
}
IF F2=1 THEN
{
//画上分型
HVALUE = REF(HHV(HIGH, N1), 1);
HFEN = HVALUE = REF(HHV(HIGH, N1), N1) AND HVALUE > REF(BASE,N1);
HORLINE( HFEN ,HVALUE ,3,2),colorred,LINETHICK1;
DAYS = BARSLAST(HFEN);
HV = REF(REF(HHV(HIGH, N1),DAYS),1);
HLAST = C>HV OR O>HV;
IF HLAST AND REF(HLAST,1) < 1 THEN
DRAWICON(1,H+INTER ,'buy1');
}
//画背景色
IF (O>BASE AND C>BASE) THEN
{
DRAWGBK(1),RGB(255,255,160);;
IF (UP>BASE AND BASE>DOWN AND C>BASE AND FLAG = 1) THEN
//上升趋势
{
DRAWGBK(1),RGB(255,255,100);
ORANGE = MA(C,M1)> MA(C,M2) AND MA(C,M2)> MA(C,M3) AND MA(C,M3)> MA(C,MAX(M3+1,ROUND(M4/2))) AND MA(C,MAX(M3+1,ROUND(M4/2)))> MA(C,MAX(M4+1,ROUND(M5/2)));
IF ORANGE AND BARSLAST(ISBEAR) >= BARSLAST(ORANGE) THEN
DRAWGBK(1),RGB(255,150,100);
}
}
ELSE
//下降趋势//www.fxjgsw.com
IF (O<BASE AND C<BASE) THEN
{
DRAWGBK(1),RGB(0,255,255);
BLUE = MA(C,M1)< MA(C,M2) AND MA(C,M2)< MA(C,M3) AND MA(C,M3)< MA(C,M4) AND MA(C,M4)< MA(C,M5);
IF BLUE AND BARSLAST(ISBEAR) > BARSLAST(ISBULL) THEN
DRAWGBK(1),RGB(80,170,255);
}
ELSE
//过渡趋势
DRAWGBK(1),RGB(255,255,160);
|
