我们经常为了查找技术指标翻遍了图面，各项指标还无法对比，能不能把它们放在一起又可在一个图上看，又可对比，要那个重叠那个就可比较，图面还不l乱，单独看谁都可以，而且把它们和主图连系起来看，即方便又有可比性，真是一举多得，我费点劲总算搞成了，奉献给大家，尽管不够完美尚需大家一起改进它，
【1】其中主力进出数据差别太大不好平衡，但是他很管用，勉强用吧，我是没其它办法了
【2】你必需把所有参数设为【0】建好模板-------在另存模板一次---参数均为0这很重要不然图就乱了，
【3】七种技术指标---MACD-----KDJ-----CCI------RSI-----DMI-----DMA-----ZLJC
【4】主图是MA5的波段线-----它不变，【要变】你把你喜欢的加进去，
INPUT:AM(1,0,1),AJ(1,0,1),AC(1,0,1),AR(1,0,1),AD(1,0,1),DM(1,0,1),ZL(1,0,1);
DRAWGBKlast(c>0,strip(RGB(0,0,0),RGB(0,0,120),0));
{1.K线}
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,8.5,0) ,COLOR000011;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,7,0) ,COLOR000033;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,6,0) ,COLOR000055;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,5,0) ,COLOR000077;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,4,0) ,COLOR000099;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,3,0) ,COLOR0000BB;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,2,0) ,COLOR0000DD;
STICKLINE((CLOSE >= OPEN),HIGH,LOW,1,0),color0000FF;
STICKLINE((OPEN >= CLOSE),CLOSE,OPEN,8.5,0),color006600;
STICKLINE((OPEN >= CLOSE),CLOSE,OPEN,7,0),color008800;
STICKLINE((OPEN >= CLOSE),CLOSE,OPEN,6,0),color00AA00;
STICKLINE((OPEN >= CLOSE),CLOSE,OPEN,5,0),color00BB00;
STICKLINE((OPEN >= CLOSE),CLOSE,OPEN,4,0),color00CC00;
STICKLINE((OPEN >= CLOSE),CLOSE,OPEN,3,0),color00DD00;
STICKLINE((OPEN >= CLOSE),CLOSE,OPEN,2,0),color00EE00;
STICKLINE((OPEN > CLOSE),HIGH,LOW,1,0),color00FF00;
LC:=REF(C,1);
卖黄金:((SMA(MAX((C - LC),0),3,1) / SMA(ABS((C - LC)),3,1)) * 100),LINETHICK0;
DRAWTEXT(CROSS(80,卖黄金) ,high*1.04,'顶'),COLOR00ffFF,ALIGN1,LINETHICK1;
STICKLINE(CROSS(80,卖黄金) AND C<O,H,L,2,0),COLOR00ffff,LAYER0;
STICKLINE(CROSS(80,卖黄金) AND C<O,C,O,12,0 ),COLOR007777,LAYER0;
STICKLINE(CROSS(80,卖黄金) AND C<O,C,O,8,0 ),COLOR009999,LAYER0;
STICKLINE(CROSS(80,卖黄金) AND C<O,C,O,6,0 ),COLOR00BBBB,LAYER0;
STICKLINE(CROSS(80,卖黄金) AND C<O,C,O,4,0 ),COLOR00DDDD,LAYER0;
STICKLINE(CROSS(80,卖黄金) AND C<O,C,O,2 ,0 ),COLOR00ffff,LAYER0;
DRAWTEXTABS(5,5,'基本指标:MA5波段'),Color00FFff,LINETHICK3;
BC:=(3*C+H+L)/5;
MA5:EMA(MA(BC,5),5);
PARTLINE(MA5,(MA5>REF(MA5,1))-1,rgb(0,255,0),1,rgb(255,0,0) ),LINETHICK2,LAYER0;
XL:=BARSLAST(DISPSTATUS=1)+1;
E:=llvall(llv(L,XL))*0.95;
IF AM=1 THEN BEGIN
DRAWTEXTABS(250,5,'技术指标:MACD'),Color0000ff,LINETHICK4;
DIFF:=EMA( EMA(CLOSE,12) - EMA(CLOSE,26),3);
DEA:=EMA(DIFF,9);
MACD:2*(DIFF-DEA),Color0598FF,LINETHICK0;;
STICKLINE(MACD>0,E+MACD*2,E,12,0),Color0598FF;
STICKLINE(MACD<0,E+MACD*2,E,12,0),ColorFF5500;
END;
IF AJ=1 THEN BEGIN
DRAWTEXTABS(250,5,'技术指标:KDJ'),Colorff00ff,LINETHICK4;
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
J:(3*K-2*D),Color05FFFF,LINETHICK0;
if(CROSS(K,D) AND BARSLAST(CROSS(D,K))<3,E*1.09,E),ColorFF9910 ;
STICKLINE(K>D,E+(K-D)/50,E,12,0),Color0000FF;
STICKLINE(K<D,E+(K-D)/50,E,12,0),Color00FF00;
END;
IF AC=1 THEN BEGIN
DRAWTEXTABS(200,5,'指标:CCI'),Color00ffff,LINETHICK4;
TYP := (HIGH + LOW + CLOSE)/3;
CCI:(TYP-MA(TYP,14))/(0.015*AVEDEV(TYP,14)),Color05FF00,LINETHICK0;;
STICKLINE(CCI>0,E+CCI/350,E,12,0),Color0077FF;
STICKLINE(CCI<0,E+CCI/350,E,12,0),ColorFF9900;
END;
IF AR=1 THEN BEGIN
DRAWTEXTABS(250,5,'技术指标:RSI'),Color00ff00,LINETHICK4;
LC := REF(CLOSE,1);
RSI:SMA(MAX(CLOSE-LC,0),14,1)/SMA(ABS(CLOSE-LC),14,1)*100,ColorFF05FF,LINETHICK0;
CRSI:="RSI.RSI3#WEEK";
金叉RSI:STICKLINE(CROSS("RSI.RSI2#WEEK","RSI.RSI3#WEEK"),E,E*1.1,0.6,0),ColorFF00FF;
DRAWTEXT(CROSS("RSI.RSI2#WEEK","RSI.RSI3#WEEK"),E*1.1,'金叉'),COLOR0000FF;
STICKLINE(RSI>CRSI,E+(RSI-CRSI)/50,E,12,0),Color0000FF;
STICKLINE(RSI<CRSI,E+(RSI-CRSI)/50,E,12,0),Color00FF00;
VAR1:=(CLOSE*2+HIGH+LOW)/4;
SK:=EMA(VAR1,13)-EMA(VAR1,73);
SD:=EMA(SK,2);
XG:=((CROSS(SK,SD) AND SK<-0.04 AND (C-REF(C,1))/REF(C,1)>=0.03) OR (CROSS(SK,SD) AND SK<=-0.14 )
OR (CROSS(SK,SD) AND SK<=0.05 AND (V/MA(V,5)>2 OR C/REF(C,1)>0.035)) OR 金叉RSI);
STICKLINE(XG,E,E*1.15,0.6,0),COLOR00FFFF;
DRAWTEXT(XG,E*1.15,'突破'),COLOR00FFBB;
END;
IF AD=1 THEN BEGIN
{DMI新编}
DRAWTEXTABS(250,5,'技术指标:DMI'),Color0598ff,LINETHICK4;
N:=21;M:=6;M1:=20;
TR1:=EMA(MAX(MAX(HIGH-LOW,ABS(HIGH-REF(CLOSE,1))),ABS(REF(CLOSE,1)-LOW)),N);
HD :=HIGH-REF(HIGH,1);
LD :=REF(LOW,1)-LOW;
DMP:=EMA(IF(HD>0 AND HD>LD,HD,0),N);
DMM:=EMA(IF(LD>0 AND LD>HD,LD,0),N);
PDI:= DMP*100/TR1;
MDI:DMM*100/TR1,Color05FFFF,LINETHICK0;
ADX:= EMA((PDI-MDI)/(MDI+PDI)*100,M)*2;
ADXR:=EMA(ADX,M);
ADMA:=EMA(ADX,M1);
OMD:=(ADX-2*ADMA+ADXR)/2;
STICKLINE( OMD>0,E,E+OMD/100,12,0),COLORRED;
STICKLINE(OMD<0,E,E+OMD/100,12,0),COLORGREEN;
END;
IF DM=1 THEN BEGIN
DRAWTEXTABS(250,5,'技术指标:DMA'),ColorFF55ff,LINETHICK4;
DDD:=(MA(CLOSE,10)-MA(CLOSE,50));
AMA:=MA(DDD,10);
STICKLINE( DDD>AMA,E,E+(DDD-AMA),12,0),COLORFF22FF;
STICKLINE(DDD<AMA,E,E+(DDD-AMA),12,0),COLOR99FF99;
END;
IF ZL=1 THEN BEGIN
DRAWTEXTABS(250,5,'技术指标:主力进出'),ColorFF55ff,LINETHICK4;
jcs:=ZLSHORT;
jcm:=ma(zlshort ,12);
STICKLINE(jcs>jcm,E,E+(jcs-jcm)/CAPITAL*5000,12,0),COLOR222299;
STICKLINE(jcs<jcm,E,E+(jcs-jcm)/CAPITAL*5000,12,0),COLORFFee00;
END;
 |
