经过一段时间的测试后，发现目前做的这个主图还可以，只要大家保持心态，按照主图的提醒去操作的话成功率相信还是可以的。
我依然是那句老话，仁者见仁！由衷的感谢那些曾经帮助过我的那些高手，谢谢！
主图源码：

{飞雪决策}
DRAWTEXT((BARPOS = SYSPARAM(2)),HIGH,((((((((((((((((('所属板块:' + BLKNAME) + '\n') + '总股本')
+ NUMTOSTR(FINANCE(1),0)) + '万股') + '  流通A股') + NUMTOSTR(FINANCE(7),0)) + '万股') + '  净资产') +
NUMTOSTR(FINANCE(35),2)) + '亿元') + '  每股收益') + NUMTOSTR(FINANCE(33),2)) + '元') +  '市盈率') +
NUMTOSTR(DYNAINFO(39),2)) + '%')),ALIGN4,colorFF00;

{公式主体}
重心价:(2*C+H+L)/4;{当日重心价}
三日重心:EMA(重心价,3),COLORBLUE,LINETHICK2;{三日重心价}

压:HHV(三日重心,20),COLORWHITE,LINETHICK2;
撑:LLV(三日重心,20),COLORWHITE,LINETHICK2;

MA10:eMA(C,10),COLORYELLOW;
MA20:MA(C,20),COLORMAGENTA;

RSV:=(CLOSE-LLV(LOW,55))/(HHV(HIGH,55)-LLV(LOW,55))*100;
K:=SMA(RSV,3,1),COLORFFFFFF;
D:=SMA(K,3,1),COLOR00FFFF;
J:=3*K-2*D,COLORFF1AA9;

DIFF:=EMA(CLOSE,7)-EMA(CLOSE,21),COLORFFFFFF,LINETHICK0;
DEA:=EMA(DIFF,3),LINETHICK0,COLOR00FFFF;
MACD:=2*(DIFF-DEA),COLOR00DDDD,LINETHICK0;

LC := REF(CLOSE,1);
RSI1:=SMA(MAX(CLOSE-LC,0),6,1)/SMA(ABS(CLOSE-LC),6,1)*100;
RSI2:=SMA(MAX(CLOSE-LC,0),12,1)/SMA(ABS(CLOSE-LC),12,1)*100;
RSI3:=SMA(MAX(CLOSE-LC,0),24,1)/SMA(ABS(CLOSE-LC),24,1)*100;
RR:=RSI1<REF(RSI1,1) AND REF(RSI1,1)>=REF(RSI1,2);

TYP:=(HIGH+LOW+CLOSE)/3;
CCI:=(TYP-MA(TYP,14))/(0.015*AVEDEV(TYP,14));
{买入}

KK:=三日重心>REF(三日重心,1) AND REF(三日重心,1)<=REF(三日重心,2);
MM2:=MA20>REF(MA20,1)*0.99 AND MA20<REF(MA20,1)*1.01;
MM:=MM2 OR MA20>=REF(MA20,1);

J55:=J>REF(J,1);
SJC:=COUNT(CROSS(J,K),15)>=1 AND J>REF(J,1) AND REF(J,1)<=REF(J,2);{双金叉}
KDJJC:=CROSS(J,K) OR SJC;

CC:=C>REF(撑,1) AND C>=REF(重心价,1);

STICKLINE(CC AND KDJJC,C,O,6.5,0),COLORMAGENTA;{KDJ金叉或又金叉显粉红柱体}
DRAWICON(KK AND MM,L*0.99,3);{决策线上行中，20日也在上行中}

SHORTBUY:=CROSS(重心价,三日重心) AND COUNT(CROSS(J,K),30)>=1 AND J>REF(J,1) AND REF(J,1)<=REF(J,2);
STICKLINE(SHORTBUY AND MACD>REF(MACD,1),C,O,4,0),COLORYELLOW;
{当日重心价,三日平均重心金叉,MACD增大，显黄柱体}

{卖出}

JXX:=J<REF(J,1);
MDD:=MACD<REF(MACD,1) AND REF(MACD,1)=HHV(MACD,3);
DRAWTEXT(MDD AND RR AND CCI<REF(CCI,1) ,H*1.01,'S'),COLORGREEN;

{主图线}

持股:PARTLINE(三日重心>REF(三日重心,1) AND J55,三日重心),COLORRED,LINETHICK2;

{黄金分割点}
高:=REF(HHV(H,80),3);
低:=REF(LLV(L,80),3);
H19:=高-(高-低)*0.191;
H38:=高-(高-低)*0.382;
H中:=高-(高-低)*0.5;
H61:=高-(高-低)*0.618;
H80:=高-(高-低)*0.809;
顶点:REFx(高,DATE),COLORWHITE,POINTDOT;
十九:REFx(H19,DATE),COLORYELLOW,POINTDOT;
三八:REFx(H38,DATE),colorgreen,POINTDOT;
五十:REFx(H中,DATE),COLORRED,POINTDOT;
六一:REFx(H61,DATE),colorgreen,POINTDOT;
八十:REFx(H80,DATE),COLORYELLOW,POINTDOT;
低点:REFx(低,DATE),COLORWHITE,POINTDOT;
DRAWTEXT(ISLASTBAR,顶点,'顶点'),COLORWHITE;
DRAWTEXT(ISLASTBAR,十九,'％19.8'),COLORYELLOW;
DRAWTEXT(ISLASTBAR,三八,'％38.2'),colorgreen;
DRAWTEXT(ISLASTBAR,五十,'％50'),COLORRED;
DRAWTEXT(ISLASTBAR,六一,'％61.8'),colorgreen;
DRAWTEXT(ISLASTBAR,八十,'％80.9'),COLORYELLOW;
DRAWTEXT(ISLASTBAR,低点,'低点'),COLORWHITE;

HJD:=CROSS(顶点,重心价) OR CROSS(低点,重心价) OR CROSS(十九,重心价)
OR CROSS(三八,重心价) OR CROSS(五十,重心价) OR CROSS(六一,重心价)
OR CROSS(八十,重心价);
HJl:=CROSS(顶点,l) OR CROSS(低点,l) OR CROSS(十九,l)
OR CROSS(三八,l) OR CROSS(五十,l) OR CROSS(六一,l)
OR CROSS(八十,l);
hjfgd:=hjd or hjl;

ma5:=ma(c,5);M10:=MA10>REF(MA10,1)*0.99 AND MA10<REF(MA10,1)*1.01;
MM10:=M10 OR MA10>=REF(MA10,1);

BC:=COUNT(CROSS(MA5,MA10),15)>=1 AND COUNT(C<REF(C,1),5)>=3 AND HJFGD
AND MM10 AND REF(C,BARSLAST(HHV(重心价,5)))/C<1.07;
DRAWTEXT(BC,L*0.988,'B'),colorwhite;
{回抽买}
T1:=BARSLAST(CROSS(压,重心价));

DRAWTEXT(MA20>REF(MA20,1) AND MA10>REF(MA10,1) AND
REF(C,T1)/LLV(L,2)<1.10 AND COUNT(C<REF(C,1),3)>=1 AND CROSS(重心价,三日重心),l*0.99,'回'+'\n'+'抽'),COLORGREEN;
{底反弹}
DRAWTEXT(COUNT(L<撑,3)>=1 AND COUNT(O/C<1.05,3)>=2 AND CROSS(重心价,撑),l*0.98,'底'),colorred;
;

鄂武商A


万象钱潮