软件名称：[B]黑马王子的量能指标[/B]
软件类型：国产软件
运行环境：Win9X/Win2000/WinXP/Win2003/Win7/
软件语言：简体中文
授权方式：免费版
软件大小：4.00 KB
官方主页：Home Page
更新时间：2016-01-11 00:23:54
软件简介:

通达信黑马王子的量能指标
 

绿低量:=13;{WEN98编制}
蓝低量:=55;
灰低量:=100;

{=====================================================}
H_L:=0.1*CONST(HHV(VOL,240));
{MAV10:MA(V,10),COLORYELLOW;}
启动5:MA(V,5),COLORWHITE;
洗盘40:MA(V,40),COLORBLUE;
异动135:MA(V,135),COLORMAGENTA;
VVOL:=IF(CURRBARSCOUNT=1 AND PERIOD=5,VOL*240/FROMOPEN,DRAWNULL);{模拟量}
STICKLINE(CURRBARSCOUNT=1 AND PERIOD=5,VVOL,0,1,-1),COLOR00C0C0;
量:VOL,VOLSTICK;
换手: VOL*10000/FINANCE(7),NODRAW; {DYNAINFO(37)*100}
换10T: SUM(换手,10),NODRAW;
倍数:=1.9;
放量: VOL>=REF(V,1)*倍数 AND (IF(C<O,C>REF(C,1),1)),COLORYELLOW,NODRAW;
缩量: REF(V,1)>=VOL*倍数,COLORMAGENTA,NODRAW;
平量: RANGE(V/REF(V,1),0.97,1.03) AND BARSCOUNT(V)>=2,COLORWHITE,NODRAW;
低量10: VOL=LLV(VOL,绿低量) AND BARSCOUNT(V)>=绿低量,COLORGREEN,NODRAW;
低量50: VOL=LLV(VOL,蓝低量) AND BARSCOUNT(V)>=蓝低量,COLORBLUE,NODRAW;
地量: VOL=LLV(VOL,灰低量) AND BARSCOUNT(V)>=灰低量,COLORGRAY,NODRAW;
假阴:C<O AND C>REF(C,1) AND VOL,VOLSTICK;

V1:=VOL*0.9;{图标位置}
V2:=VOL*0.8;
STICKLINE(放量, 0,V1,1,0),COLORYELLOW;
STICKLINE(平量,0,V1,1,0),COLORWHITE;
STICKLINE(低量10,0,V2,1,0),COLORLIGREEN;
STICKLINE(低量50,0,V2,1,0),COLORBLUE;
STICKLINE(地量,0,V2,1,0),COLORGRAY;
STICKLINE(缩量,0,V*0.45,1,0),COLORMAGENTA;
STICKLINE(C<O AND C>REF(C,1),0,V,0,0),COLORRED;{假阴柱}
真阳或假阴:=C>O OR C>REF(C,1);
收阳:= REF(真阳或假阴,3);
放量1:=REF(放量,3);
高量:=REF(V,3)>=HHV(V,7);
三日不破:= LLV(C,3)>=REF(L,3);
价升:=COUNT(C>=REF(C,1),3)=3;{收盘价逐升}
量缩:=COUNT(V<=REF(V,1),3)=3;
连阳:= COUNT(真阳或假阴,3)=3;
放量将军柱:= 放量1 AND 三日不破 AND 收阳;
高量将军柱:= 高量 AND 三日不破 AND 收阳;
将军柱:= 放量将军柱 OR 高量将军柱;
黄金柱:= 将军柱 AND 价升 AND 量缩 AND 连阳 ;
STICKLINE(黄金柱,0.3*V,0.7*V,1,0),COLORRED; {红柱}
DRAWICON(黄金柱,V*1.5,1);
V100:= V<=LLV(V,100)*1.2 AND V>0 AND BARSCOUNT(V)>=100;
百日地量群:=COUNT(V100,5)>=3;
DRAWTEXT(FILTER(百日地量群,4),V+3*H_L,'地量群'),COLORGRAY;
长阴短柱:=C/REF(C,1)<=0.96 AND V<HHV(V,30)/1.9;
DRAWTEXT(长阴短柱 ,V+1.6*H_L,'！'),COLORLICYAN;
 

[url=http://www.70822.com/soft/sort013/sort05/down-93376.html]黑马王子的量能指标[/url]