五彩K线标 - 分析家公式网

分析家公式网,提供指标公式,股票软件用户登录 |

当前位置：分析家公式网 → 股票公式 → 通达信公式 → 一键转帖：五彩K线标

软件名称：[B]五彩K线标[/B]
软件类型：国产软件
运行环境：Win9X/Win2000/WinXP/Win2003/Win7/
软件语言：简体中文
授权方式：免费版
软件大小：6.00 KB
官方主页：Home Page
更新时间：2014-07-16 05:32:48
软件简介:

经过整理，把所有的五彩K线指标反映在主图上，有一定的参考作用。可能好多人炒了多年的股，还不知道其中的含义。
它的含义和作用，可以百度一下，会有明确的答案。
名称：五彩K线标

十字星:=CLOSE=OPEN AND HIGH>LOW;
DRAWTEXT(十字星,L,'{1}十字星');
早晨之星:=(REF(CLOSE,2)/REF(OPEN,2)<0.95)&&
(REF(OPEN,1) < REF(CLOSE,2))&&
(ABS(REF(OPEN,1)-REF(CLOSE,1))/REF(CLOSE,1)<0.03) && 
CLOSE/OPEN>1.05 && CLOSE>REF(CLOSE,2);
DRAWTEXT(早晨之星,L*1.02,'{2}早晨之星');
黄昏之星:=REF(CLOSE,2)/REF(OPEN,2)>1.05&&
REF(OPEN,1)>REF(CLOSE,2)&&
ABS(REF(OPEN,1)-REF(CLOSE,1))/REF(CLOSE,1)<0.03&&
CLOSE/OPEN<0.95&&CLOSE<REF(CLOSE,2);
DRAWTEXT(黄昏之星,L,'{3}黄昏之星');
长十字:=CLOSE=OPEN&&HIGH/LOW>1.03;
DRAWTEXT(长十字,L*1.02,'{4}长十字');
身怀六甲:=ABS(REF(CLOSE,1)-REF(OPEN,1))/REF(CLOSE,1)>0.04&&
ABS(CLOSE-OPEN)/CLOSE<0.005&&
MAX(CLOSE,OPEN)<MAX(REF(CLOSE,1),REF(OPEN,1))&&
MIN(CLOSE,OPEN)>MIN(REF(CLOSE,1),REF(OPEN,1));
DRAWTEXT(身怀六甲,L,'{5}身怀六甲');
三个白武士:=UPNDAY(CLOSE,3)&&NDAY(CLOSE,OPEN,3);
DRAWTEXT(三个白武士,L*1.01,'{6}三个白武士');
三只乌鸦:=DOWNNDAY(CLOSE,3)&&NDAY(OPEN,CLOSE,3);
DRAWTEXT(三只乌鸦,L,'{7}三只乌鸦');
光头阳线:=HIGH=CLOSE&&HIGH>LOW;
DRAWTEXT(光头阳线,H,'{8}光头阳线'),COLORMAGENTA;
光脚阴线:=LOW=CLOSE&&HIGH>LOW;
DRAWTEXT(光脚阴线,L,'{9}光脚阴线');
垂死十字:=CLOSE=OPEN&&CLOSE=LOW&&CLOSE<HIGH;
DRAWTEXT(垂死十字,L,'{10}垂死十字');
早晨十字星:=REF(CLOSE,2)/REF(OPEN,2)<0.95&&
REF(OPEN,1)<REF(CLOSE,2)&&
REF(OPEN,1)=REF(CLOSE,1)&&
CLOSE/OPEN>1.05&&CLOSE>REF(CLOSE,2);
DRAWTEXT(早晨十字星,L,'{11}早晨十字星');
黄昏十字星:=REF(CLOSE,2)/REF(OPEN,2)>1.05&&
REF(OPEN,1)>REF(CLOSE,2)&&
REF(OPEN,1)=REF(CLOSE,1)&&
CLOSE/OPEN<0.95&&CLOSE<REF(CLOSE,2);
DRAWTEXT(黄昏十字星,L,'{12}黄昏十字星');
射击之星:=MIN(OPEN,CLOSE)=LOW&&
HIGH-LOW>3*(MAX(OPEN,CLOSE)-LOW)&&
CLOSE>MA(CLOSE,5);
DRAWTEXT(射击之星,L,'{13}射击之星');
倒转锤头:=MIN(OPEN,CLOSE)=LOW&&
HIGH-LOW>3*(MAX(OPEN,CLOSE)-LOW)&&
CLOSE<MA(CLOSE,5);
DRAWTEXT(倒转锤头,L,'{14}倒转锤头');
锤头:=HIGH=MAX(OPEN,CLOSE)&&
HIGH-LOW>3*(HIGH-MIN(OPEN,CLOSE))&&
CLOSE<MA(CLOSE,5);
DRAWTEXT(锤头,L*1.03,'{15}锤头');
吊颈:=HIGH=MAX(OPEN,CLOSE)&&
HIGH-LOW>3*(HIGH-MIN(OPEN,CLOSE))&&
CLOSE>MA(CLOSE,5);
DRAWTEXT(吊颈,L*1.03,'{16}吊颈');
穿头破脚:=(REF(CLOSE,1)/REF(OPEN,1)>1.03&&
CLOSE/OPEN<0.96&&
CLOSE<REF(OPEN,1)&&OPEN>REF(CLOSE,1))||
(REF(CLOSE,1)/REF(OPEN,1)<0.97&&
CLOSE/OPEN>1.04&&
CLOSE>REF(OPEN,1)&&OPEN<REF(CLOSE,1));
DRAWTEXT(穿头破脚,L,'{17}穿头破脚');
AA:=VOL>REF(VOL,1)||VOL>(CAPITAL*0.1);
BB:=OPEN>=(REF(HIGH,1))&&REF(HIGH,1)>(REF(HIGH,2)*1.06);
CC:=CLOSE>(REF(CLOSE,1))-(REF(CLOSE,1)*0.01);
DD:=CLOSE<(HIGH*0.965) && HIGH>(OPEN*1.05);
EE:=LOW<OPEN && LOW<CLOSE&&HIGH>(REF(CLOSE,1)*1.06);
FF:=(HIGH-(MAX(OPEN,CLOSE)))/2>(MIN(OPEN,CLOSE))-LOW;
GG:=(ABS(OPEN-CLOSE))/2<(MIN(OPEN,CLOSE)-LOW);
剑:=AA&&BB&&CC&&DD&&EE&&FF&&GG;
DRAWTEXT(剑,L,'{18}剑');
A:=CLOSE>OPEN;
B:=A&&CLOSE>MA(CLOSE,20)&&CLOSE>MA(CLOSE,40)&&CLOSE>MA(CLOSE,60);
C1:=B&&OPEN<MA(CLOSE,40)&&OPEN<MA(CLOSE,60);
出水芙蓉:=C1&&(CLOSE-OPEN)>0.0618*CLOSE;
DRAWTEXT(出水芙蓉,L*1.04,'{19}出水芙蓉');
大阳烛:=CLOSE/OPEN>1.05 AND HIGH/LOW < CLOSE/OPEN+0.018;
DRAWTEXT(大阳烛,L,'{20}大阳烛');
大阴烛:=OPEN/CLOSE>1.05 AND HIGH/LOW<OPEN/CLOSE+0.018;
DRAWTEXT(大阴烛,L,'{21}大阴烛');
长下影:=(MIN(CLOSE,OPEN)-LOW)/(HIGH-LOW)>0.667;
DRAWTEXT(长下影,L,'{22}长下影'),COLORMAGENTA;
长上影:=(HIGH-MAX(CLOSE,OPEN))/(HIGH-LOW)>0.667,COLORBLUE;
DRAWTEXT(长上影,L,'{23}长上影'),COLORGREEN;
乌云盖顶:=REF(CLOSE,1)/REF(OPEN,1)>1.03 AND CLOSE/OPEN<0.97 AND OPEN>REF(CLOSE,1) AND CLOSE<REF(CLOSE,1); 
DRAWTEXT(乌云盖顶,L,'{24}乌云盖顶'),COLORGREEN;
曙光初现:=REF(CLOSE,1)/REF(OPEN,1)<0.97 AND CLOSE/OPEN>1.03 AND OPEN<REF(CLOSE,1) AND CLOSE>REF(CLOSE,1); 
DRAWTEXT(曙光初现,L,'{25}曙光初现'),COLORGREEN;
平顶:=ABS(HIGH-REF(HIGH,1))/HIGH<0.001; 
DRAWTEXT(平顶,L,'{26}平顶'),COLORGREEN;
平底:=(ABS(LOW-REF(LOW,1))/LOW<0.001 AND ABS(REF(LOW,1)-REF(LOW,2))/REF(LOW,1)<=0.001); 
DRAWTEXT(平底,L,'{27}平底'),COLORGREEN;
红三兵:=REF(CLOSE,2)>REF(OPEN,2) AND REF(CLOSE,1)>REF(OPEN,1) AND CLOSE>OPEN 
AND REF(CLOSE,1)>REF(CLOSE,2) AND CLOSE>REF(CLOSE,1); 
DRAWTEXT(红三兵,L*1.02,'{28}红三兵'),COLORLIMAGENTA;
双飞乌鸦:=REF(CLOSE,1)<REF(OPEN,1) AND CLOSE<OPEN AND CLOSE/OPEN<0.98; 
DRAWTEXT(双飞乌鸦,L,'{29}双飞乌鸦'),COLORGREEN;
孕育线:=REF(CLOSE,2)>REF(OPEN,2) AND (REF(CLOSE,2)-REF(OPEN,2))/REF(OPEN,2)>=2/100  AND REF(OPEN,1)>=REF(CLOSE,1) AND 
(REF(OPEN,1)-REF(CLOSE,1))/REF(CLOSE,1)<=2/100 AND REF(OPEN,1)<=REF(CLOSE,2) AND REF(CLOSE,1)>=REF(OPEN,2) AND C>=OPEN AND 
(CLOSE-OPEN)/OPEN>=2/100 AND CLOSE>=REF(OPEN,1) AND OPEN<=REF(CLOSE,1) AND (MAX(CLOSE,REF(C,2))-MIN(CLOSE,REF(CLOSE,2)))/MIN(CLOSE,REF(CLOSE,2))<=1/100; 
DRAWTEXT(孕育线,L,'{30}孕育线'),COLORGREEN;
多方炮:=REF(CLOSE,2)>REF(OPEN,2) AND REF(CLOSE,1)<REF(OPEN,1) AND CLOSE>OPEN; 
DRAWTEXT(多方炮,L,'{31}多方炮'),COLORGREEN;
好友反攻:=(REF(CLOSE,1)<REF(OPEN,1) AND CLOSE>OPEN AND ABS(CLOSE-REF(CLOSE,1))/CLOSE<0.002) 
OR (REF(CLOSE,1)>REF(OPEN,1) AND CLOSE<OPEN AND ABS(CLOSE-REF(CLOSE,1))/CLOSE<0.002); 
DRAWTEXT(好友反攻,L,'{32}好友反攻'),COLORGREEN;
倾盆大雨:=REF(C,1)/REF(O,1)>=1.03 AND O<REF(C,1) AND O>REF(O,1) AND C<REF(O,1); 
DRAWTEXT(倾盆大雨,L,'{33}倾盆大雨'),COLORGREEN;

[url=http://www.70822.com/soft/sort013/sort05/down-74370.html]五彩K线标[/url]