当前位置：分析家公式网 → 股票公式 → 通达信公式 → 一键转帖：【犀牛K白色】主图，K线涨停高亮-白色背景 本指标犀牛哥作
软件名称：[B]【犀牛K白色】主图，K线涨停高亮-白色背景 本指标犀牛哥作[/B]
软件类型：国产软件
运行环境：Win10/Win9X/Win8/Win2000/WinXP/Win2003/Win7/
软件语言：简体中文
授权方式：分享版
软件大小：3.00 KB
官方主页：Home Page
更新时间：2024-06-06 06:14:48
软件简介:
【犀牛K白色】主图，K线涨停高亮-白色背景 本指标犀牛哥作
昨天发布了一个黑色的K线图，其实还有这个白色K线的，也一起分享出来。
指标源码：
{通达信K线高亮指标
指标配色优美，支持注册制前后的涨幅高亮，
涨幅大于10%也高亮，跌停、炸板也有提示
结合同通达信涨停插件使用效果更佳，
插件地址 百度搜索“犀利猫”，进入首页找：通达信涨停插件
黄色：涨停，
橙色：涨幅大于10个点未涨停，
深橙色：涨幅大于20个点未封板，
绿色：跌停或跌幅大于10个点，
浅紫色：炸板阳线，
深紫色：炸板阴线，
白色虚线：现价线
竖线分割：创业板改革日期}
{均线，均线可以根据需要修改}
ZDJS:=IF(CODELIKE('880005'), 1, 0);
M5:IF(ZDJS=0,MA(C,5),DRAWNULL);
M10:IF(ZDJS=0,MA(C,10),DRAWNULL);
M20:IF(ZDJS=0,MA(C,20),DRAWNULL);
M40:IF(ZDJS=0,MA(C,40),DRAWNULL);
M250:IF(ZDJS=0,MA(C,250),DRAWNULL);
{下一行是板块调用，也可以改为扩展数据调用，例如 EXTERNSTR(0,1) }
DRAWTEXT_FIX(1,0.003,0.02,0, STRCAT(HYBLOCK,STRCAT(' + ', STRCAT(GNBLOCK,STRCAT('+ ', FGBLOCK))))),COLORBLACK;
{涨跌家数880005 指标：情绪高低潮分割线}
N1:DRAWSL(ZDJS=1,3200,0,1000,1), COLORRED;
N2:DRAWSL(ZDJS=1,720,0,1000,1), COLORGREEN;
{现价线}
N:CONST(C), COLORBLACK, POINTDOT;
{填充线宽度}
W1:=3;
W0:=0;
{判断涨跌幅限制，涨跌停价格}
CYB:=IF(INBLOCK('创业板'), 1, 0);
ZDF:=IF(FINANCE(3)=3 OR FINANCE(3)=4, 0.2,
IF(FINANCE(3)=2, 0.3,
IF(NAMEINCLUDE('ST'), 0.05,
0.1)
)
);
ZT:=ZTPRICE(REF(CLOSE,1), ZDF);
DT:=DTPRICE(REF(CLOSE,1), ZDF);
ZT1:=ZTPRICE(REF(CLOSE,1), 0.1)+0.01;
ZT2:=ZTPRICE(REF(CLOSE,1), 0.2)+0.01;
DT1:=DTPRICE(REF(CLOSE,1), 0.1);
DT2:=DTPRICE(REF(CLOSE,1), 0.2);
{非创业板涨跌停}
NOCYB:=CYB=0 AND ZDJS=0;
STICKLINE((NOCYB AND C+0.01>=ZT AND C=H), O, C, W1, 0),COLOR007FFF;
STICKLINE((NOCYB AND C<=DT AND C=L), O, C, W1, 0),COLORGREEN;
STICKLINE((NOCYB AND L<=DT AND C<ZT AND C>L), L, C, 0, 0),COLORGREEN;{曾跌停阳线}
{炸板}
STICKLINE((NOCYB AND C<ZT AND H=ZT AND C>DT AND C<O), O, C, W1, 0), COLORFF4D88;
STICKLINE((NOCYB AND C<ZT AND H=ZT AND C>O), O, C, W1, 0), COLORFF4DFF;
{创业板改革日分割线}
GGR:=1200824;{改革日}
STICKLINE(DATE=GGR AND (CYB=1 OR CODELIKE('8808')), CONST(LLV(L,120)), CONST(HHV(H,120)), W0, 0),COLOR5C979C;
{创业板涨停跌停}
STICKLINE((CYB=1 AND DATE>=GGR AND C>=ZT2 AND C=H), O, C, W1, 0), COLOR007FFF;
STICKLINE((CYB=1 AND DATE<GGR AND C>=ZT AND C=H), O, C, W1, 0), COLOR007FFF;
STICKLINE((CYB=1 AND DATE<GGR AND C<=DT AND C=L), O, C, W1, 0), COLORGREEN;
{炸板}
STICKLINE((CYB=1 AND DATE<GGR AND C<ZT AND H=ZT AND C>DT AND C<O), O, C, W1, 0), COLORFF4DFF;
STICKLINE((CYB=1 AND DATE<GGR AND C<ZT AND H=ZT AND C>O), O, C, W1, 0), COLORFF4DFF;
STICKLINE((CYB=1 AND DATE>=GGR AND C<ZT AND H=ZT2 AND C>DT AND C<O), O, C, W1, 0), COLORFF4DFF;
{所有板块：涨跌幅大于10个点}
STICKLINE((C>ZT1 AND C<ZT2 AND C>O AND ZDJS=0), O, C, W1, 0), COLOR00AAFF;
STICKLINE((C<H AND C>ZT2 AND C>O AND ZDJS=0), O, C, W1, 0), COLOR0066CC;
STICKLINE((C<=DT1 AND C<O AND ZDJS=0), O, C, W1, 0), COLORGREEN;
[url=http://www.70822.com/soft/sort013/sort05/down-173827.html]【犀牛K白色】主图，K线涨停高亮-白色背景 本指标犀牛哥作[/url]