软件名称：[B]通达信解盘难题 - 东家《系统买点》[/B]
软件类型：国产软件
运行环境：Win9X/Win2000/WinXP/Win2003/
软件语言：简体中文
授权方式：免费版
软件大小：4.00 KB
官方主页：Home Page
更新时间：2010-03-17 11:10:29
软件简介:

选股有主副图选股、条件选股、排序选股、交易系统等多种方法，这些方法都有不同的优缺点，副图选股直观、能很好地与主图配合，便于分析趋势走向，能即时拿取数据和选择。虽然不能像条件选股和排序选股那样进行批量选股，也不像交易系统那样只列出一个指标的多空买卖，但它对自选的几只股的多种监控却比其它的方法直接，大家都喜欢用它。
   
        为解决通达信本身设置限制使解盘指标少的难题，我用分栏列出和遮掩的方法进行了尝试，经过多次的试验测试，将通达信的交易系统里的KDJ、KD、MACD、RSI、DMI、CCI、BOLL、ROC、MTM、BIAS、PSY 、VR等买卖指标都放了进去，通过副图即时自动测算个股并将信号列出，左边栏可作解盘或加附言，左边长条栏内的信号为即时的，用日线为当日，用60分钟为一小时内的判定，将通达信的交易系统同时显示，对持股持币选择有指导性作用，极为方便。

        此指标的使用是用作对自选股分析趋势走向，选择持股持币用的，所以要求使用者对系统参数有一定的认识，不同于《八仙过海》、《六指金叉》、《十全十美》、《六点共振》等指标，这类指标多是见红色箭头超过多少个买进，少于多少个卖出，操作容易，但不是要求大家用以分析。初学者可选此类指标。
   
        作为长期投资，长线买进应选CCI、BIAS、BOLL等，中短线买入宜用RSI、MACD、KDJ、VR等，追涨可用ROC、MTM等.60分钟RIS作为短线进出最理想，可以说能避过历次的险峰。
   
        本指标的公开纯属抛砖引玉作为交流，给大家作为参考，希望能看到更多的新作品出现。

N:=11;
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
LC:=REF(C,1);
CCI背:=IF(LLV(CCI,2)>LLV(CCI,7) AND LLV(L,2)<=LLV(L,7)  AND HHV(H,10)>MA(CLOSE,60),1,0),COLORWHITE;
A1:=BARSLAST(REF(CROSS("MACD.DIF"(12,26,9),"MACD.DEA"(12,26,9)),1));
B1:=REF(C,A1+1)>C && REF("MACD.DIF"(12,26,9),A1+1)<"MACD.DIF"(12,26,9) && CROSS ("MACD.DIF"(12,26,9),"MACD.DEA"(12,26,9));
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
J:=3*K-2*D;
KL:=CROSS(J,0);
WRSI:=SMA(MAX(CLOSE-LC,0),6,1)/SMA(ABS(CLOSE-LC),6,1)*100;
RL:=CROSS(WRSI,20);
WVR := SUM((IF(CLOSE>OPEN,VOL,0)+IF(CLOSE=OPEN,VOL/2,0)),26)/SUM((IF(CLOSE<OPEN,VOL,0)+IF(CLOSE=OPEN,VOL/2,0)),26)*100;
BIAS买入:= CROSS(-6,(CLOSE-MA(CLOSE,12))/MA(CLOSE,12)*100);
PSY买入:= CROSS(10,PSY(12,1));
VR买入:= CROSS(70,WVR);
MID :=MA(CLOSE,20);
LOWER:=MID-2*STD(CLOSE,20);
布林:=CROSS(CLOSE,LOWER);
WROC:=ROC(12,6);
变动速率:=CROSS(WROC,0);
TR:=SUM(MAX(MAX(HIGH-LOW,ABS(HIGH-REF(CLOSE,1))),ABS(LOW-REF(CLOSE,1))),14);
HD :=HIGH-REF(HIGH,1);
LD :=REF(LOW,1)-LOW;
PDM:=SUM(IF(HD>0&&HD>LD,HD,0),14);
MDM:=SUM(IF(LD>0&&LD>HD,LD,0),14);
PDI:=PDM*100/TR;
MDI:=MDM*100/TR;
趋向:=CROSS(PDI,MDI);
WRSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
WK:=SMA(WRSV,3,1);
DN:=SMA(WK,3,1);
KD买:=CROSS(WK,DN)&&WK<20;
WMTM:=MTM;
MTM买:=CROSS(WMTM,0);
DRAWBAND(110,RGB(80,50,0),-10,RGB(0,150,255));
STICKLINE(CURRBARSCOUNT=1 ,110,-10,4,0),COLOR333344;
DRAWTEXT(CCI背 AND REF(CCI,1)<-150  AND C>O,100,'C'),COLORYELLOW;
DRAWTEXT(KL,100,'K'),COLORWHITE;
DRAWTEXT(KD买,90,'KD'),COLORFF00FF;
DRAWTEXT(趋向,80,' D'),COLORFF00FF;
DRAWTEXT(RL,70,'R'),COLORGREEN;
DRAWTEXT(布林,60,' BL'),COLORFF00FF;
DRAWTEXT(B1,50,'M'),COLORYELLOW;
DRAWTEXT(BIAS买入,40,' BA'),COLORRED;
DRAWTEXT(PSY买入,30,' P'),COLORYELLOW;
DRAWTEXT(MTM买,10,' MT'),COLORFF00FF;
DRAWTEXT(VR买入,20,' V'),COLORFF00FF;
DRAWTEXT(变动速率,0,' RC'),COLORFF00FF;

STICKLINE(CURRBARSCOUNT=56 ,110,-10,60,0),COLOR333344;
DRAWTEXT(CURRBARSCOUNT=59,100,'C=CCI      K=KDJ'),COLORGREEN;
DRAWTEXT(CURRBARSCOUNT=59,90,'KD  随机指标'),COLORGREEN;
DRAWTEXT(CURRBARSCOUNT=59,80,'D=DMI  趋向指标'),COLORGREEN;
DRAWTEXT(CURRBARSCOUNT=59,70,'R=RSI  相对强弱'),COLORGREEN;
DRAWTEXT(CURRBARSCOUNT=59,60,'BL=BOLL  布林指标'),COLORGREEN;
DRAWTEXT(CURRBARSCOUNT=59,50,'M=MACD  平滑异同平均'),COLORGREEN;
DRAWTEXT(CURRBARSCOUNT=59,40,'BA=BIAS   乖离率指标 '),COLORGREEN;
DRAWTEXT(CURRBARSCOUNT=59,30,'P=PSY    心理线指标 '),COLORGREEN;
DRAWTEXT(CURRBARSCOUNT=59,20,'MT=MTM  动量线指标'),COLORGREEN;
DRAWTEXT(CURRBARSCOUNT=59,10,'V=VR  容量比率指标'),COLORGREEN;
DRAWTEXT(CURRBARSCOUNT=59,0,'RC=ROC   变动速率指标 '),COLORGREEN;

[url=http://www.70822.com/soft/sort013/sort05/down-17357.html]通达信解盘难题 - 东家《系统买点》[/url]