分析家公式网,提供指标公式,股票软件 用户登录  |  用户 注册

软件名称:[B]必然上涨的指标公式分享[/B]
软件类型:国产软件
运行环境:Win9X/Win2000/WinXP/Win2003/Win7/
软件语言:简体中文
授权方式:免费版
软件大小:3.00 KB
官方主页:Home Page
更新时间:2018-09-28 01:27:24
软件简介:

1、倍量过左锋选股(选股公式)
SR1:=REF(HIGH,10)=HHV(HIGH,2*10+1);
SR2:=FILTER(SR1,10);
SR3:=BACKSET(SR2,10+1);
HD:=FILTER(SR3,10);
前高:=REF(H,BARSLAST(HD));
倍量:=VOL/REF(VOL,1)>=1.9;
突破前高:CROSS(C,前高);
2、评台线及黄金数(主图指标)

{双10+20日量能}
MA(C,3);
N:=5;
T1:=CONST(HHVBARS(V,N));
T0:IF(CURRBARSCOUNT<=N+3,CONST(IF(T1=0,C,REF(C,T1))),DRAWNULL),COLORFF00FF;
IF(CURRBARSCOUNT=T1+1,T0,DRAWNULL),CIRCLEDOT,COLORFF00FF;
DRAWTEXT(ISLASTBAR,T0,' 量能评台'),COLORCCCCCC;
{分析家公式网www.70822.com}
W:=21;
W1:=CONST(REF(HHVBARS(V,W),T1+1)+T1+1);
W0:IF(CURRBARSCOUNT<=T1+W+3 AND CURRBARSCOUNT>=T1+1,CONST(REF(C,W1)),DRAWNULL),COLOR009999;
IF(CURRBARSCOUNT=W1+1,W0,DRAWNULL),CIRCLEDOT,COLOR00CCCC;

M:=34;
Q1:=CONST(REF(HHVBARS(V,M),T1+1)+T1+1);
Q0:IF(CURRBARSCOUNT<=T1+M+3 AND CURRBARSCOUNT>=T1+1,CONST(REF(C,Q1)),DRAWNULL),COLOR009900;
IF(CURRBARSCOUNT=Q1+1,Q0,DRAWNULL),CIRCLEDOT,COLOR00CC00;
R:=88;
Y1:=CONST(REF(HHVBARS(V,R),T1+1)+T1+1);
Y0:IF(CURRBARSCOUNT<=T1+R+3 AND CURRBARSCOUNT>=T1+1,CONST(REF(C,Y1)),DRAWNULL),COLOR119911;
IF(CURRBARSCOUNT=Y1+1,Y0,DRAWNULL),CIRCLEDOT,COLORCC00CC;
所属地域:DRAWTEXT_FIX(ISLASTBAR ,0.88,1,1,DYBLOCK),COLORYELLOW;
所属行业:DRAWTEXT_FIX(ISLASTBAR ,0.91,1,0,HYBLOCK),COLORYELLOW;
DRAWTEXT_FIX(1,0.00,0.18,0,'主题投资:')COLORWHITE;
DRAWTEXT_FIX(1,0.09,0.18,0,EXTERNSTR(0,1))COLORWHITE;
DRAWTEXT_FIX(1,0.00,0.26,0,'主营业务:')COLORFF00FF;
DRAWTEXT_FIX(1,0.09,0.26,0,EXTERNSTR(0,2))COLORFF00FF;

STICKLINE(C/REF(C,1)>=1.045 AND C/REF(C,1)<=1.095,C,O,3,0),COLORB0B0FF;
{涨停变黄颜色}
STICKLINE(C>1.095*REF(C,1),C,O,2.5,0),COLORYELLOW;
VARZT:=BARSLAST(C/REF(C,1)>1.097);
DRAWTEXT(VARZT=2,L*0.95,'3天'),COLORYELLOW;
DRAWTEXT(VARZT=4,H*1.06,'5天'),COLORYELLOW;
DRAWTEXT(VARZT=7,L*0.95,'8天'),COLORYELLOW;
DRAWTEXT(VARZT=12,H*1.06,'13天'),COLORYELLOW;
DRAWTEXT(VARZT=20,L*0.95,'21天'),COLORYELLOW;
DRAWTEXT(VARZT=33,H*1.06,'34天'),COLORYELLOW;
DRAWTEXT(VARZT=54,L*0.95,'55天'),COLORYELLOW;
DRAWTEXT(VARZT=88,H*1.06,'89天'),COLORYELLOW;

3、MACD指标二次翻红选股(选股公式)
DIFF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
FH1:=REF(MACD,1)<REF(MACD,2) AND REF(MACD,2)<REF(MACD,3) AND REF(MACD,3)<REF(MACD,4);
FH2:=MACD>=0 AND COUNT(MACD>REF(MACD,1),1)=1;
FH3:=EMA(C,30)>=REF(EMA(C,30),1) AND COUNT(EMA(C,5)>EMA(C,10) AND EMA(C,10)>EMA(C,30),1)=1;
FH4:=CROSS(C,EMA(C,30)) OR C>EMA(C,30);
FH5:=FH1 AND FH2 AND FH3 AND FH4;
FH6:=FH1 AND FH2 AND FH3 AND FH4 AND ABS((DIFF-DEA)/C)<0.018;
FH7:=FH1 AND FH2 AND FH3 AND FH4 AND MACD<0.10;
FH5 OR FH6 OR FH7;

4、涨停变黄s(主图指标)
{涨停变黄颜色}
STICKLINE(C>1.095*REF(C,1),C,O,2.5,0),COLORYELLOW;


5、涨幅5-9.5 变粉色(主图指标)

STICKLINE(C/REF(C,1)>=1.045 AND C/REF(C,1)<=1.095,C,O,2.5,0),COLORB0B0FF;

6、必然上涨量柱 黄金柱 假阴真阳柱(附图指标)

{VOL_量柱}
{看图说明:黄s为倍量柱,白色为并肩平量柱,紫色为缩倍柱,
绿色为10天低量柱,蓝色为50天低量柱,灰色为百日低量柱,
高量柱容易看无标记,!为长阴短柱, 内有红实线为假阴柱。
红色箭头(的前三天)为黄金柱。次黄金柱难判,不标记}

绿低量:=13;{WEN98编制}
蓝低量:=55;
灰低量:=100;

H_L:=0.1*CONST(HHV(VOL,240));
{MAV10:MA(V,10),COLORYELLOW;}
启动5:MA(V,5),COLORWHITE;
洗盘35:MA(V,35),COLORGREEN;
异动135:MA(V,135),COLORMAGENTA;

VVOL:=IF(CURRBARSCOUNT=1 AND PERIOD=5,VOL*240/FROMOPEN,DRAWNULL);{模拟量}
STICKLINE(CURRBARSCOUNT=1 AND PERIOD=5,VVOL,0,1,-1),COLOR00C0C0;
量:VOL,VOLSTICK;
换手: VOL*10000/FINANCE(7),NODRAW; {DYNAINFO(37)*100}
换10T: SUM(换手,10),NODRAW;
倍数:=1.9;
倍量: VOL>=REF(V,1)*倍数 AND (IF(C<O,C>REF(C,1),1)),COLORYELLOW,NODRAW;
倍缩: REF(V,1)>=VOL*倍数,COLORMAGENTA,NODRAW;
平量: RANGE(V/REF(V,1),0.97,1.03) AND BARSCOUNT(V)>=2,COLORWHITE,NODRAW;
低量10: VOL=LLV(VOL,绿低量) AND BARSCOUNT(V)>=绿低量,COLORGREEN,NODRAW;
低量50: VOL=LLV(VOL,蓝低量) AND BARSCOUNT(V)>=蓝低量,COLORBLUE,NODRAW;
地量: VOL=LLV(VOL,灰低量) AND BARSCOUNT(V)>=灰低量,COLORGRAY,NODRAW;

V1:=VOL*0.9;{图标位置}
V2:=VOL*0.8;
STICKLINE(倍量, 0,V1,1,0),COLORYELLOW;
STICKLINE(平量,0,V1,1,0),COLORWHITE;
STICKLINE(低量10,0,V2,1,0),COLORLIGREEN;
STICKLINE(低量50,0,V2,1,0),COLORBLUE;
STICKLINE(地量,0,V2,1,0),COLORGRAY;
STICKLINE(倍缩,0,V*0.45,1,0),COLORMAGENTA;
STICKLINE(C<O AND C>REF(C,1),0,V,0,0),COLORRED;{假阴柱}
真阳或假阴:=C>O OR C>REF(C,1);
收阳:= REF(真阳或假阴,3);
倍量1:=REF(倍量,3);
高量:=REF(V,3)>=HHV(V,7);
三日不破:= LLV(C,3)>=REF(L,3);
价升:=COUNT(C>=REF(C,1),3)=3;{收盘价逐升}
量缩:=COUNT(V<=REF(V,1),3)=3;
连阳:= COUNT(真阳或假阴,3)=3;
倍量将军柱:= 倍量1 AND 三日不破 AND 收阳;
高量将军柱:= 高量 AND 三日不破 AND 收阳;
将军柱:= 倍量将军柱 OR 高量将军柱;
黄金柱:= 将军柱 AND 价升 AND 量缩 AND 连阳 ;
STICKLINE(黄金柱,0.3*V,0.7*V,1,0),COLORRED; {红柱}
DRAWICON(黄金柱,V*1.5,1);
V100:= V<=LLV(V,100)*1.2 AND V>0 AND BARSCOUNT(V)>=100;
百日地量群:=COUNT(V100,5)>=3;
DRAWTEXT(FILTER(百日地量群,4),V+3*H_L,'地量群'),COLORGRAY;
长阴短柱:=C/REF(C,1)<=0.96 AND V<HHV(V,30)/1.9;
DRAWTEXT(长阴短柱 ,V+1.6*H_L,'!'),COLORLICYAN; 均价:=AMOUNT/VOL/100;
TJ01:=C<O AND 均价>REF(C,1);{假阴真阳};
TJ02:=C<O AND C>REF(C,1);
STICKLINE(TJ01 OR TJ02,0,V,0,0),COLORRED;{假阴柱};
7、阳盖双阴(选股指标)

{阳线后的双阴}

T1:=REF(C>O,3);

T2:=REF(C<O,2);

T3:=REF(C<O,1);

{一阳盖双阴}

T4:=C>O;

T5:=C>REF(O,2) AND C>REF(O,1);

{双阴缩量}

T6:=VOL>REF(VOL,1) AND VOL>REF(VOL,2);

T7:=REF(VOL,3)>REF(VOL,2) AND REF(VOL,3)>REF(VOL,1);

选股:T1&&T2&&T3&&T4&&T5&&T6&&T7;

8、板后阴(选股指标)

ZT:=(C-REF(C,1))*100/REF(C,1)>=(10-1/REF(C,1)) AND
(C-REF(C,1))*100/REF(C,1)<=(10+1/REF(C,1)) AND H=C;
COUNT(C<O,BARSLAST(ZT)+1)=1 AND C<O;

9、盘后一字板选股
最低价:=L<O;
ZF:=(C-REF(C,1))/REF(C,1)*100;
涨停:=ZF>9.9;
XG:=C=O;
去除ST股:=EXIST((C-REF(C,1))/REF(C,1)*100>5.6,100);{最近100日存在涨幅大于5.6}
去除停牌:=DYNAINFO(17)!=0;{量比不为0}
选股: 最低价 AND XG AND 涨停 AND 去除ST股 AND 去除停牌;
10、盘中一字板打开预警(装选股公式栏)
XG:=REF(C,1)*1.1-C<0.01 AND H=O AND H>=C AND H!=L;

去除ST股:=EXIST((C-REF(C,1))/REF(C,1)*100>5.6,100);{最近100日存在涨幅大于5.6}
去除停牌:=DYNAINFO(17)!=0;{量比不为0}
选股: XG AND 去除ST股 AND 去除停牌;


[url=http://www.70822.com/soft/sort013/sort03/down-129119.html]必然上涨的指标公式分享[/url]

关于本站 | 网站帮助 | 广告合作 | 声明 | 友情连接 | 网站地图 |
分析家公式网声明:本站所有股票公式软件资料均网上公开收集,如侵权请联系删帖。站内所有广告,均与本站无关!
Copyright © 2003-2024 70822.Com. All Rights Reserved .
页面执行时间:62.50000 毫秒