MA11:MA(CLOSE,10),COLORRED;
MA33:MA(CLOSE,30),COLORYELLOW;
MA55:MA(CLOSE,55),COLORBLUE;
年线:MA(CLOSE,250),COLORGREEN;
Y:=(MA(C,11)-MA(C,55))/MA(C,11)*100;
{135均线战法}      
      
YY1:=C>MA(C,11) AND OPEN<MA(C,11);{一阳三线}  
YY3:=C>MA(C,33) AND OPEN<MA(C,33);
YY5:=C>MA(C,55) AND OPEN<MA(C,55);
DRAWTEXT(YY1 AND YY5 AND YY3,LOW-0.1,'一阳三线'),COLORRED;

SJ1:=ABS(MA(CLOSE,11)-MA(CLOSE,33))<C*0.01;{１１线３３线５５线接近}  
SJ2:=ABS(MA(CLOSE,33)-MA(CLOSE,55))<C*0.01;  
SJ3:=CROSS(MA(CLOSE,11),MA(CLOSE,55));{11线上穿５５线}  
DRAWTEXT(SJ1 AND SJ2 AND SJ3,HIGH+0.1,'三军集合'),COLORRED;

RY1:=C/OPEN>1.04;{阳线４％}  
RY2:=REF(OPEN,1)/REF(CLOSE,1)>1.04;{阴线４％}
RY3:=ABS(OPEN-REF(C,1))<C*0.02 AND ABS(C-REF(OPEN,1))<C*0.02;{两线相等}
DRAWTEXT(RY1 AND RY2 AND RY3 ,LOW,'日月合璧'),COLORYELLOW;

HK1:=CROSS(MA(C,11),MA(C,55));{11线上穿５５线}
HK2:=C<O;{当日收阴}
HK3:=ABS(L-MA(C,11))<C*0.03 OR ABS(C-MA(C,11))<C*0.04;{收盘价或最低价在１１线}
HK:=HK1 AND HK2 AND HK3;
DRAWTEXT(HK,LOW,'黑客》》 '),COLORGREEN;

JG1:=ABS(MA(C,11)-MA(C,33))<C*0.02 AND ABS(MA(C,11)-MA(C,55))<C*0.02;
JG2:=O>MA(C,11) OR O=MA(C,11);
JG3:=C/OPEN>1.03 ; {阳线３％}  
JG:=JG1 AND JG2 AND JG3;
DRAWTEXT(JG,LOW-0.2,'揭竿而起'),COLORYELLOW;

HY1:=CROSS(MA(C,11),MA(C,55));{11线上穿５５线}
HY2:=OPEN<C AND C/OPEN>1.02; {阳线３％}
HY3:=ABS(OPEN-MA(C,11))<C*0.05;{开盘在１１线附近}  
HY:=HY1 AND HY2 AND HY3;
DRAWTEXT(HY,LOW,'红衣侠女'),COLORRED;

JW1:=C<OPEN AND REF(C,1)<REF(OPEN,1);
JW2:=OPEN<REF(C,1) AND C>REF(L,1);
JW3:=O<MA(C,11) AND O<MA(C,33) AND O<MA(C,55);
JW:=JW1 AND JW2 AND JW3;
DRAWTEXT(JW,LOW-0.2,'金屋藏娇'),COLORYELLOW;

TS1:=CROSS(MA(C,11),MA(C,33));{11线上穿33线}
TS2:=MA(C,11)<MA(C,55);
TS:=TS1 AND TS2;
DRAWTEXT(TS,LOW-0.2,'投石问路'),COLORF00FF0;

MK1:=MA(C,11)>MA(C,55) AND MA(C,33)>MA(C,55);
MK:=TS1 AND MK1;
DRAWTEXT(MK,H+0.4,'梅开二度'),COLORF00FF0;

YZ1:=C/O>1.02 AND H/C>1.02 AND O/L<1.02;{收阳有上影}
YZ2:=REF(C,1)>REF(O,1) AND O>MA(C,11);{昨收阳 今大于均线}
YZ:=YZ1 AND YZ2 AND Y>10;
DRAWTEXT(YZ,HIGH+0.2,'一枝独秀'),COLORF00FF0;

DS1:=OPEN/C>1.04 AND O/REF(C,1)>1.03;{高开收阴}
DS2:=V*100/FINANCE(7)>0.08 AND Y>8;{换手高涨幅大}
DS:=DS1 AND DS2;
DRAWTEXT(DS,HIGH+0.2,'独上高楼'),COLORGREEN;

YJ1:=H/O>1.04;
YJ2:=ABS(C-O)<C*0.03;
YJ3:=C/MA(C,11)>1.1;
YJ:=YJ1 AND YJ2 AND DS2 AND YJ3 AND YZ2;
DRAWTEXT(YJ,HIGH+0.3,'一剑封喉'),COLORRED;